import processing.opengl.*;



// camera settings
float eyeX = 311;
float eyeY = 55;
float eyeZ = -275;
float viewX = 400;
float viewY = 50;
float viewZ = 0;
float camSpeed = 5;

// like pixel arrays, led brightness addresses from top left, 
// increments to the right by one, and end bottom right
// fill this array to add content
// each brighness is ranging from black = 0.0 to green = 255.0
float[] ledBrightness = new float[300];
// temp is used for interpolated change
float[] ledBrightnessTemp = new float[300];

// bouncing ball variables
float ballX = 0;
float ballY = 0;
float ballXSpeed = 0;  
float ballYSpeed = 0; 

// noise scale used for Perlin Noise generation 
float noiseScale=0.12;
float noiseZ = 0.0;

void setup() {
	size(800, 400, OPENGL); 
	colorMode(HSB, 100); 
	frameRate(30); 
	
	// generate bouncing ball direction
	ballXSpeed = random(6.0);  
	ballYSpeed = random(2.0);
	
} 
 
void draw() { 
	background(0,0,0);
	//lights
	pointLight(0, 0, 100, 35, 600, -400);
	pointLight(20, 50, 70, 200, 20, 15);


	// content
	if (second() < 10) {
		if (frameCount%60 == 0) randomNoise();
		interpolateLeds(6);
	} else if (second() < 20) {
		waveLight();
	} else if (second() < 30) {
		niceSine();
	} else if (second() < 40) {
		bounceBall();
	} else if (second() < 50) {
		if (frameCount%1 == 0) randomNoise();
		interpolateLeds(1);
	} else if (second() < 60) {
		perlinNoise();
	}
	
	
	
	// draw
	drawFacade();
	drawLeds();

	// see
	camera(eyeX, eyeY, eyeZ, viewX, viewY, viewZ, 0.0, -1.0, 0.0);
	navigation();
}


// CONTENT **********************************************************************

void perlinNoise(){
	for(int i = 0; i<ledBrightness.length; i++){
		float x = i%60;
		float y = floor(i/60);
		noiseZ += 0.0002;
		float noiseVal = noise(x*noiseScale, y*noiseScale, noiseZ) * 255;
		ledBrightness[i] = 0;
		if (noiseVal > 100 && noiseVal < 130) ledBrightness[i] = 255;
	}
}

void bounceBall() {
	ballX += ballXSpeed;
	ballY += ballYSpeed;
	
	if (ballX > 60 || ballX < 0) ballXSpeed = -ballXSpeed;
	if (ballY > 5 || ballY < 0) ballYSpeed = -ballYSpeed;
	
	for(int i = 0; i<ledBrightness.length; i++){
		
		float x = i%60;
		float y = floor(i/60);
		ledBrightness[i] = 0;
	
		float treshold = abs(x - ballX) + abs(y - ballY);
		ledBrightness[i] = (255 - treshold*50)%255;
		
	}
}


void waveLight() {
	for(int i = 0; i<ledBrightness.length; i++){
		ledBrightness[i] = sin(radians( (i%60)*10 + frameCount*20 ))*255;
	}
}

void niceSine() {
	for(int i = 0; i<ledBrightness.length; i++){
		float x = i%60;
		float y = floor(i/60);
		int step = frameCount * 30;
		float xScale = frameCount%40;
		ledBrightness[i] = 0;
		float treshold =  -0.4 + y / 2.5 - sin(radians(x * xScale + step));
		if (treshold > 0 && treshold < 0.5) ledBrightness[i] = 255;
	}
}

void randomNoise() {
	for(int i = 0; i<ledBrightness.length; i++){
		ledBrightnessTemp[i] = random(255);
	}
}

void interpolateLeds(float speed) {
	for(int i = 0; i<ledBrightness.length; i++){
		ledBrightness[i] -= (ledBrightness[i] - ledBrightnessTemp[i]) / speed;
	}
}


// REST ***********************************************************************

// draws 300 leds in place
void drawLeds() {
	noStroke();
	pushMatrix();
	translate(200, 82, 10);
	for(int i = 0; i<ledBrightness.length; i++){
		
		if (i%10==0 && i%60!=0 && i%20!=0){
			translate(18, 0, 0);
		} 
		
		if (i%60==0 && i!=0){
			translate(-(5 * 54) -(3 * 18) -(2 * 65), - 8, 0);
		} else if (i%20 == 0 && i!=0){
			translate(65, 0, 0);
		}
		
		if (i%10!=0 && i!=0) {
			translate(5, 0, 0);
		}
		
		// color fill
		// emitting color, so LEDs are not affected by scene lights
		emissive(40, 100, ledBrightness[i]/2.55);
		fill(40, 100, ledBrightness[i]/2.55);

		// led
		box(1, 1, 2);

		// simple shine effect
		float shineSize = max(ledBrightness[i] / 70, 1); 
		fill(40, 100, ledBrightness[i]/2.55, 30);

		pushMatrix();
		rotateZ(radians(45));
		box(shineSize, shineSize, 0.1);
		rotateZ(radians(45));
		box(shineSize, shineSize, 0.1);
		popMatrix();
		
		// reset emission so other materials don't glow
		emissive(0, 0, 0);
	}
	popMatrix();

}


// draws 3d facade model
void drawFacade() {
	pushMatrix();

	// draw ornament
	fill(0, 50, 70);
	noStroke();
	
	pushMatrix();
	for (int j=0; j<4; j++){
		translate(170, 0, 0);
		pushMatrix();
		for(int i=0; i<4; i++){
			box(50, 25, 4);
			translate(0, 27, 0);
		}
		popMatrix();
	}
	popMatrix();
	
	// draw wall
	noStroke();
	pushMatrix();
	fill(0, 50, 50);
	translate(430, 10, 10);
	box(600, 65, 10);
	translate(0, 90, 0);
	box(600, 20, 10);
	popMatrix();
	
	translate(165, 40, 10);
	box(60, 120, 10);
	translate(174, 0, 0);
	box(60, 120, 10);
	translate(174, 0, 0);
	box(60, 120, 10);
	translate(174, 0, 0);
	box(60, 120, 10);
	
	translate(-85, 0, 0);
	box(12, 120, 10);
	translate(-174, 0, 0);
	box(12, 120, 10);
	translate(-174, 0, 0);
	box(12, 120, 10);
	
	// top house
	fill(0, 50, 30);
	translate(160, 210, -10);
	box(600, 300, 10);

	// inside
	translate(0, -200, 30);
	rotateX(radians(-15));
	fill(0, 0, 30);
	box(600, 200, 2);
	popMatrix();
	
	// grounds
	pushMatrix();
	fill(0, 0, 30);
	translate(440, -60, 0);
	box(600, 90, 10);
	fill(0, 0, 20);
	box(800, 1, 200);
	popMatrix();
	
	// window frames
	stroke(0, 100, 0);
	line(180, 43, 10, 660, 43, 10);
	line(180, 55, 10, 660, 55, 10);
	line(180, 60, 10, 660, 60, 10);
	line(180, 70, 10, 660, 70, 10);
	line(180, 75, 10, 660, 75, 10);
	line(180, 89, 10, 660, 89, 10);
	
	pushMatrix();
	for (int i=0; i<100; i++){
		line(180 + i*5.2, 43, 10, 180 + i*5.2, 89, 10);
	}
	
	popMatrix();
}


// keyboard navigation
void navigation() { 
	// navigation
	if (keyPressed){
		if (key == 'a'){
			eyeX -= camSpeed;
		} else if (key == 'd'){
			eyeX += camSpeed;
		} else if (key == 'r'){
			eyeY += camSpeed;
		} else if (key == 'f'){
			eyeY -= camSpeed;
		} else if (key == 'w'){
			eyeZ += camSpeed;
			//viewZ -= camSpeed;
		} else if (key == 's'){
			eyeZ -= camSpeed;
			//viewZ += camSpeed;
		}
		//println(eyeX);
		//println(eyeZ);
	}
}